Module Eio.Promise

A promise is a placeholder for result that will arrive in the future.

Unlike lazy values, you cannot "force" promises; a promise is resolved when the maker of the promise is ready.

Promises are thread-safe and so can be shared between domains and used to communicate between them.

Example:

let promise, resolver = Promise.create () in
Fiber.both
  (fun () -> traceln "Got %d" (Promise.await promise))
  (fun () -> Promise.resolve resolver 42)
type !+'a t

An 'a t is a promise for a value of type 'a.

type !-'a u

An 'a u is a resolver for a promise of type 'a.

val create : ?label:string -> unit -> 'a t * 'a u

create () is a fresh promise/resolver pair. The promise is initially unresolved.

val create_resolved : 'a -> 'a t

create_resolved x is a promise that is already resolved with result x.

val await : 'a t -> 'a

await t blocks until t is resolved. If t is already resolved then this returns immediately.

val resolve : 'a u -> 'a -> unit

resolve u v resolves u's promise with the value v. Any threads waiting for the result will be added to the run queue.

  • raises Invalid_argument

    if u is already resolved.

val try_resolve : 'a u -> 'a -> bool

try_resolve is like resolve but returns false instead of raising Invalid_argument.

Returns true on success.

val peek : 'a t -> 'a option

peek t is Some v if the promise has been resolved to v, or None otherwise. If the result is None then it may change in future, otherwise it won't. If another domain has access to the resolver then the state may have already changed by the time this call returns.

val is_resolved : 'a t -> bool

is_resolved t is Option.is_some (peek t).

Result promises

type 'a or_exn = ('a, exn) Stdlib.result t
val resolve_ok : ('a, 'b) Stdlib.result u -> 'a -> unit

resolve_ok u x is resolve u (Ok x).

val resolve_error : ('a, 'b) Stdlib.result u -> 'b -> unit

resolve_error u x is resolve u (Error x).

val await_exn : 'a or_exn -> 'a

await_exn t is like await t, but if the result is Error ex then it raises ex.